Imprimer

[RMistral (Wisi)]

Bonjour,

Voilà les lignes que je te propose. Chez moi cela fonctionne. Le principe comme T_bo te l'explique est de ne pas essayer d'appliquer le style tant que le style n'est pas présent. Entre le moment ou je demande et le moment ou j'ai le temps passe et l'animation continue..... (C'est comme dans la vie ca )

Code: [Sélectionner]

//Création d'une occurrence de l'objet LoadVars pour réceptionner les données
var lireTexteExterne:LoadVars = new LoadVars();
lireTexteExterne.onLoad = function(disponible:Boolean):Void  {
//Si les données sont disponibles
if (disponible) {
//j'applique la feuille de style sur du texte qui est forcèment présent
ZnTexte.styleSheet = Style;
ZnTexte.html = true;
ZnTexte.htmlText = this.dbtexte;

} else {
//Sinon avertir l'utilisateur
Alerte.text = "Fichier non disponible sur le serveur";
}
};

//importation de la classe externe feuille de style
import TextField.StyleSheet;
//Création d'une occurrence de feuille de style
var Style:StyleSheet = new StyleSheet();
//fonction de chargement de la feuille de style externe
Style.onLoad = function(disponible:Boolean):Void  {
if (disponible) {
//Appel des données externes maintenant que je dispose de la feuille de style
lireTexteExterne.load("Album.txt");
} else {
alerte.text = "La feuille de style n'est pas disponible";
}
};
/////////////////////////////////////// Corps du programme ///////////////////////////////////////////////////////
//Appel de la feuille de style
Style.load("style.css");Bon courage pour le MovieClipLoader

[Chrys]

Bonjour,

Voilà les lignes que je te propose. Chez moi cela fonctionne. Le principe comme T_bo te l'explique est de ne pas essayer d'appliquer le style tant que le style n'est pas présent. Entre le moment ou je demande et le moment ou j'ai le temps passe et l'animation continue..... (C'est comme dans la vie ca )

Effectivement, ton code marche très bien.

Bon courage pour le MovieClipLoader

Merci je vais en avoir besoin, vu le temps que j'ai passé pour pondre le code du haut !!!
Pour cette partie , ben, je suis pas sorti du sable !!

Je me suis fais un petit fichier texte, de ta recette a suivre un peu plus haut dans les messages.

Si j'ai bien suivi, il faut que je me fasse une "Boite" (MovieClipLoader) dans laquelle il y aura du text, une image et une anime.
Cette "Boite" doit être vide, et je dois faire en sorte que je puisse en chercher tant que j'en ai besoin (suivant le nombre d'album).
A la racine de tout ça, je doit avoir trois dossiers "fournisseur":
1 pour le texte (de chaque album)
1 pour les images (jacquette de chaque album)
1 pour les swf (que j'ai pu récupéré de l'ancien site)

Donc en réalité, je travail en aveugle, sur des composants vide.
Qui ensuite se rempliront, grace au code.

Bon … ben c'est parti !! :/

Chrys

[Chrys]

Bon alors voila ma première tentative pour un MCL.

le code ci dessous est un mélange entre, des codes trouvé de ci de la, la notice Flash etc …

code

Code: [Sélectionner]

//je créer un clip vide.
var conteneur:MovieClip = this.createEmptyMovieClip("album", this.getNextHighestDepth());
var mclListener:Object = new Object();
 
mclListener.onLoadInit = function(target_mc:MovieClip):Void
{
    conteneur._x = 0; //je place mon image 0 pixels du bord gauche.
    conteneur._y = 10;//et a 10 pixels du haut.
}

var mcl:MovieClipLoader = new MovieClipLoader();
mcl.addListener(mclListener);
 
//chargement de mon image.
mcl.loadClip("img/couv1.jpg", conteneur);le soucis, c'est que lorsque l'on va a la pêche comme ça, on ne comprends pas tjrs ce qu'il se passe.

Chrys

[RMistral (Wisi)]

Bonjour Chrys,

Je te propose de découper le travail. En résumé tu sais charger un texte externe et tu sais appliquer une feuille de style externe. Maintenant il faut maitriser le MovieClipLoader. Dans un troisième temps tu mélangeras les 2 puis nous verrons les boucles.

Pour le MovieClipLoader il faut bien comprendre le principe.

Il faut créer une occurrence de l’objet MoviClipLoader puis un objet Ecouteur chargé de nous prévenir quand quelque chose arrive.

Il y a 5 événements qui peuvent survenir en cours de chargement. onLoadStart (quand commence le chargement), onLoadProgress (combien d’octect chargés sur un total de combien), onLoadComplete (le dernier octet est là mais le fichier n’est pas encore disponible), onLoadInit (Ca y est nous pouvons jouer avec), onLoadError (Ca tourne au cauchemar y a un problème)

Le seul événement obligatoire à programmer est onLoadInit qui nous indique la disponibilité du fichier. C’est à partir de là que je suis en mesure de manipuler mon MC de réception.

Donc voilà le code associé :

Code: [Sélectionner]

///////////////////////////////////////////////////////////////////////// Chargement fichiers externes
//Création d'une occurrence de l'objet MovieClipLoader pour gestion du chargement JPG, SWF, GIF, PNG
var ChargementFichier:MovieClipLoader = new MovieClipLoader();
/*Création d'un objet d'écoute chargé de nous décrire ce qui se passe pendant le chargement*/
var EcouteurDeChargement:Object = new Object();
//Fonction gérant le début du chargement
EcouteurDeChargement.onLoadStart = function(clipActuel:MovieClip):Void  {
    //Message ça commence
    Alerte.text = "Le chargement débute"
    Alerte._visible = true;
};
//Fonction gérant l'arrivée des octets
EcouteurDeChargement.onLoadProgress = function(clipActuel:MovieClip, octetsCharger:Number, totalACharger:Number) {
    //Message Déjà disponible
    Alerte.text = "Déjà disponible .."+((Math.round(octetsCharger/1024)*100)/100)+" Ko / "+((Math.round(totalACharger/1024)*100)/100)+" Ko";
    Alerte._visible = true;
};
//Fonction gérant la fin du chargement
EcouteurDeChargement.onLoadComplete = function(clipActuel:MovieClip):Void  {
    //Message disponible
    Alerte.text = "Le fichier est complètement chargé"
    Alerte._visible = true;
};
//Fonction gérant l'exécution de la première image  de l'élément chargé
EcouteurDeChargement.onLoadInit = function(clipActuel:MovieClip):Void  {
    Alerte.text = "";
    Alerte._visible = false
   //Position de la photo en x et y
    clipActuel._x = 0
    clipActuel._y = 0
    }
};
//Fonction gérant les erreurs de chargement
EcouteurDeChargement.onLoadError = function(clipActuel:MovieClip, codeErreur:String,numeroErreur:Number):Void  {
    Alerte.text = codeErreur + " " + numeroErreur
    Alerte._visible = true;
};
//Activation de l'écouteur de chargement
ChargementFichier.addListener(EcouteurDeChargement);Il faut créer un MC vide pour recevoir le fichier que nous souhaitons charger puis il suffit d'apeler notre MCL pour charger à la demande le fichier jpg, gif, swf, ou png.

Code: [Sélectionner]

//Création du MC Album en niveau 0 sur la scène
this.createEmptyMovieClip("Album1",0, 1);
//Création dans le MC Album d'un MC Photo en profondeur 0
Album1.createEmptyMovieClip("PhotoAlbum",0, 1);
//Appel au MCL pour charger la photo de l'album
ChargementFichier.loadClip("URL de la Photo à charger",Album1.PhotoAlbum);Essaye puis nous verrons la suite....

[Chrys]

Bonjour,

Et oui, ca marche super bien évidemment !!!

J'ai bien évidemment, une question a poser par ligne quasiment .
je vois par exemple que tu as ajouté des fonctions mathématiques (si j'ai bien suivis) :
…((Math.round(octetsCharger/1024)*100)/100)+" Ko / "+((Math.round(totalACharger/1024)*100)/100)+" Ko";

Tout nouveau pour moi .

la ou je me pause le plus de question (en ce moment), c'est sur la gestion de la Mise en page. Càd, pour le placement de chaque module, comment va t'on pouvoir gérer les hauteurs et largeurs en pixels, des différent éléments.

mais , j'imagine que cela arrivera en toute fin des travaux.

Chrys

Pour celles et ceux qui suivent cette évolution avec grand intérêt (comme moi), ligne 32 = "};" inattendu.

[RMistral (Wisi)]

Bonne nuit,

La ligne en question (facultative) permet d'afficher arrondi en Ko le nombre de Ko chargé et le nombre de KO à charger en temps réel. Le onLoadProgress transmet les 2 valeurs (dispo,total) en octet. Pour faire propre l'affichage est calculé en Ko

Pour la mise en page il suffit de jouer sur les positions _x,_y dans le onLoadInit ainsi que sur le _width et/ou le _height toujours dans le onLoadInit.

Ton image n'est disponible et utilisable que dans le onLoadInit.

Maintenant si cela fonctionne essaye de mixer le chargement de la photo de l'album et le texte descriptif et la feuille de style en un seul fichier fla.


Bon courage....

[Chrys]

Maintenant si cela fonctionne essaye de mixer le chargement de la photo de l'album et le texte descriptif et la feuille de style en un seul fichier fla.

Bonsoir,

Oui ca fonctionne pour l'image.

Pour la tentative de mixage avec le texte/CSS, la seule chose que j'obtiens, c'est de voir mon texte dans la fenetre de sortie, mais pas d'erreur. Dans le swf résultant, je vois que l'image.
Pourtant, crois bien que j'ai essayé en mettant mon code d'import du texte , partout dans tout les sens … ou alors, il doit m'en manquer un !! ( de sens !) :rolleyes:

Chrys

[RMistral (Wisi)]

Bonjour Chrys,

Bien voilà le grand moment !!!!!

Nous allons essayer de créer dynamiquement un MC Album1 sur la scène. Ce MC contenant un MC PhotoAlbum en profondeur 0 et une zone de texte Descriptif en profondeur 1. A toi de rajouter par la suite dans Album1 un MC titre en profondeur 2.

Sur ta scène juste une zone de texte dynamique nommée : Alerte pour afficher les messages d'erreurs

Sur un calque ActionScript le code suivant :

Code: [Sélectionner]

///////////////////////////////////////////////////////////////////////// Chargement fichiers externes
//Création d'une occurrence de l'objet MovieClipLoader pour gestion du chargement JPG, SWF, GIF, PNG
var ChargementFichier:MovieClipLoader = new MovieClipLoader();
/*Création d'un objet d'écoute chargé de nous décrire ce qui se passe pendant le chargement*/
var EcouteurDeChargement:Object = new Object();
//Fonction gérant le début du chargement
EcouteurDeChargement.onLoadStart = function(clipActuel:MovieClip):Void  {
//Message ça commence
Alerte.text = "Le chargement débute";
Alerte._visible = true;
};
//Fonction gérant l'arrivée des octets
EcouteurDeChargement.onLoadProgress = function(clipActuel:MovieClip, octetsCharger:Number, totalACharger:Number) {
//Message Déjà disponible
Alerte.text = "Déjà disponible .." + ((Math.round(octetsCharger / 1024) * 100) / 100) + " Ko / " + ((Math.round(totalACharger / 1024) * 100) / 100) + " Ko";
Alerte._visible = true;
};
//Fonction gérant la fin du chargement
EcouteurDeChargement.onLoadComplete = function(clipActuel:MovieClip):Void  {
//Message disponible
Alerte.text = "Le fichier est complètement chargé";
Alerte._visible = true;
};
//Fonction gérant l'exécution de la première image  de l'élément chargé
EcouteurDeChargement.onLoadInit = function(clipActuel:MovieClip):Void  {
Alerte.text = "";
Alerte._visible = false;
//Position de la photo en x et y à toi de voir les positions
clipActuel._x = 0;
clipActuel._y = 0;
};

//Fonction gérant les erreurs de chargement
EcouteurDeChargement.onLoadError = function(clipActuel:MovieClip, codeErreur:String, numeroErreur:Number):Void  {
Alerte.text = codeErreur + " " + numeroErreur;
Alerte._visible = true;
};
//Activation de l'écouteur de chargement
ChargementFichier.addListener(EcouteurDeChargement);
///////////////////////////////////////////////////////////////////////////////// Chargement du texte externe
//Création d'une occurrence de l'objet LoadVars pour réceptionner les données
var lireTexteExterne:LoadVars = new LoadVars();
lireTexteExterne.onLoad = function(disponible:Boolean):Void  {
//Si les données sont disponibles
if (disponible) {
//j'applique la feuille de style sur du texte qui est forcèment présent
Album1.Descriptif.styleSheet = Style;

Album1.Descriptif.htmlText = this.dbtexte;
} else {
//Sinon avertir l'utilisateur
Alerte.text = "Fichier non disponible sur le serveur";
}
};

////////////////////////////////////////////////////////////////// importation de la classe externe feuille de style
import TextField.StyleSheet;
//Création d'une occurrence de feuille de style
var Style:StyleSheet = new StyleSheet();
//fonction de chargement de la feuille de style externe
Style.onLoad = function(disponible:Boolean):Void  {
if (disponible) {
//Appel des données externes
lireTexteExterne.load("Style.txt");
} else {
alerte.text = "La feuille de style n'est pas disponible";
}
};
/////////////////////////////////////// Corps du programme ///////////////////////////////////////////////////////
//Appel de la feuille de style
Style.load("style.css");
//Création du MC Album en niveau 0 sur la scène
this.createEmptyMovieClip("Album1",0, 1);
//Création dans le MC Album d'un MC Photo en profondeur 0
Album1.createEmptyMovieClip("PhotoAlbum",0, 1);
/*Création d'une zone de texte dans album pour recevoir le descriptif de l'album
A toi de mettre ici les bonnes dimensions en fonction de la taille et de la position de l'image de l'album*/
Album1.createTextField("Descriptif",1,PositionX,PositionY,Largeur,Hauteur);
Album1.Descriptif.multiline = true;
Album1.Descriptif.html = true;
//Appel au MCL pour charger la photo de l'album
ChargementFichier.loadClip("URL de la Photo à charger",Album1.PhotoAlbum);Il ne restera plus que l'étape boucle pour réaliser ton projet.

Bon courage ......

[Chrys]

Bonjour RMistral,

Et merci, j'avance a grand pas !!
C'est vraiment TOP, j'ai aussi réussi a importer mon Titre (en swf) en profondeur 2.
Par contre, je n'arrive pas a agir sur les mesures de placement, j'ai bien tenté comme avec le MC Texte (en changeant la profondeur et les autres mesures) :

[c]Album1.createTextField("Descriptif",1,220,95,450,213);[/c]

Mais j'ai l'impression qu'il dépend du MC image ! Le titre se place au même endroit, pourtant il n'est pas sur la meme profondeur.
Ci dessous, la partie du code que j'ai changé pour ajouter le titre :

Code: [Sélectionner]

///////////////////// Corps du programme ///////////////////////////
//Appel de la feuille de style
Style.load("style.css");

//Création du MC Album en niveau 0 sur la scène
this.createEmptyMovieClip("Album1",0, 1);

//Création dans le MC Album d'un MC Photo en profondeur 0
Album1.createEmptyMovieClip("PhotoAlbum",0, 1);

//Création dans le MC Album d'un MC Titre en profondeur 2
Album1.createEmptyMovieClip("TitreAlbum",2);

/*Création d'une zone de texte dans album pour recevoir le descriptif de l'album en profondeur 1
A toi de mettre ici les bonnes dimensions en fonction de la taille et de la position de l'image de l'album*/
Album1.createTextField("Descriptif",1,220,95,450,213);
Album1.Descriptif.multiline = true;
Album1.Descriptif.html = true;

//Appel au MCL pour charger la photo de l'album
ChargementFichier.loadClip("img/couv1.jpg",Album1.PhotoAlbum);

//Appel au MCL pour charger le swf Titre de l'album
ChargementFichier.loadClip("swf/LudPrei.swf",Album1.TitreAlbum);Je l'est nommé TitreAlbum.

Merci

Chrys

[RMistral (Wisi)]

Bonjour,


Ok la construction du MC  Album1.createEmptyMovieClip("TitreAlbum",2) est bonne.

L'appel au fichier swf externe aussi : ChargementFichier.loadClip("swf/LudPrei.swf",Album1.TitreAlbum);

Maintenant il te faut travailler dand le onLoadInit du MovieClipLoader. Là avec un if ou un switch il faut réagir en fonction du nom (TitreAlbum ou Photoalbum) pour positionner et mettre à la taille à l'aide de TitreAlbum._x, TitreAlbum._y, TitreAlbum._width, TitreAlbum._height et PhotoAlbum._x, PhotoAlbum._y, PhotoAlbum._width, PhotoAlbum._height

Code: [Sélectionner]

//Fonction gérant l'exécution de la première image  de l'élément chargé
EcouteurDeChargement.onLoadInit = function(clipActuel:MovieClip):Void  {
Alerte.text = "";
Alerte._visible = false;
switch (clipActuel._name) {
case "PhotoAlbum" :
clipActuel._x = Position x
clipActuel._y = Position y
//Taille si besoin ou clipActuel._xscale, clipActuel._yscale
clipActuel._width = taille horizontale
clipActuel._height = taille verticale
break;
case "TitreAlbum" :
clipActuel._x = Position x
clipActuel._y = Position y
//Taille si besoin ou clipActuel._xscale, clipActuel._yscale
clipActuel._width = taille horizontale
clipActuel._height = taille verticale
break;
}
};Voilà essaye çà et bon code.....

[Chrys]

Bonjour,

Et oui, et pouff.

En faites, j'imagine qu'en faisant attention aux profondeurs, en commençant par "case" et terminant par "break", on pourrait ajouter un tas de fichiers !?

C'est passionnant …

Et étonnant, surtout quand je vois que mon fichier fla comporte la scène avec une couleur de fond et un seul calque "actions".

Chrys

PS : une question tout de même, qu'elle est la différence entre :
[c]._xscale / ._yscale[/c]
et
[c]._width /._height[/c]

[RMistral (Wisi)]

Bonjour,

Bravo belle réussite.

_width permet de donner ou de lire la taille en pixels d'un MC idem pour _height

_xscale, _yscale permet de modifier en % la taille d'un MC 100% égale échelle 1 c'est à dire la taille actuelle de ton MC

Pour garder l'homothétie il suffit de formuler de la manière suivante :

Code: [Sélectionner]

MonMC._xscale=MonMC._yscale=75Pour le switch il suffit de rajouter des "case" autant qu'un évêque peut en bénir...

Voilà la prochaine étape c'est de mettre l'Album dans une boucle pour créer à la volée x Albums.

Je t'explique çà après le salon Intergraphic.


Bonne journée...

[Chrys]

Bonjour,

Merci pour ces précisons, que je vais m'empresser de tester

Ok, pas de soucis pour la suite :cool: , et je te souhaite … un bon salon

Bonne journée à toi …

Chrys

[Chrys]

Bonjour,

Bien, j'ai bien tout suivi ce que tu indique ici. (mais apparemment non !)

Mis le code que tu me donne, biensur j'ai opéré qq changements suivant les dimensions et nom.

dont a la place de :

Code: [Sélectionner]

//importation de la classe externe feuille de style
import TextField.StyleSheet;
//Création d'une occurrence de feuille de style
var Style:StyleSheet = new StyleSheet();
//fonction de chargement de la feuille de style externe
Style.onLoad = function(disponible:Boolean):Void  {
    if (disponible) {
        //Appel des données externes
        lireTexteExterne.load("Style.txt");
    } else {
        alerte.text = "La feuille de style n'est pas disponible";
    }
};part :

[c][large]lireTexteExterne.load("textes/Album"+i+".txt", AlbumActuel);[/large][/c]

J'ai bon ?

Quand je test, j'ai un seul album et dans le panneau de sorti aucuns messages d'erreur. Gulp !
Je n'arrive pas a trouver ou j'ai fauté

Chrys

[T_bo]

A vu de nez et en lisant  rapidement je dirais que si tu ne vois que le dernier album de ta liste...
 c'est que tu ne fais pas intervenir i dans le positionnement y de ton AlbumActuel comme te la dit notre mistral gagnant ?  
genre :
    AlbumActuel._x = 0
    //Position verticale de l'album sur la scene : (La hauteur de l'album + espace de x pixel en dessous) * i
    AlbumActuel._y = 50*i -50

car si le code etait bugger tu ne verrais rien du tout... (apres j'ai pas tout relu en detail non plus mais j'ai toute confiance dans le scripteur)